refactor!: change layout; import and build change

Fixes: #200
Fixes: #365
Fixes: #512
Fixes: #800

fix(pyproject): resolve mix-up of mypy and pytest

chore(ci): remove legacy scripts

chore: format with new mypy rules; fix translation test

wip(ci/mypy): remove config flag

fix(pyinstaller): use correct dict access

fix(resources): usage in ts_qt.py

feat(nix/package): validate tests with pytest hook

fix(nix/package): remove old dependency patch

feat(nix): support Darwin

fix(nix/package): move check deps to checkInputs

fix(nix/shell): typo

fix(nix/shell): correctly wrap Python with Qt args

fix(pyproject): specify mypy-extensions

feat(nix/package): provide pillow-jxl-plugin

nix(nix/package): split into multiple files, allow overriding of JXL and vtf2img

fix(nix/shell): provide FFmpeg on runtime

feat(flake): output pillow-jxl-plugin and vtf2img

fix(nix/package): load pipewire

feat(nix/package): run tests on pillow-jxl-plugin

fix: remove extra noqa comment

docs: update installation docs

docs: shrink table size on docs site

nit(nix/package): pipewire not needed in buildInputs

docs: update commands, environment, setup

fix: use consistent possessives

chore: format with prettier, add ignore flags

fix(pyinstaller): consume from pyproject

Revert "fix(pyinstaller): consume from pyproject"

This reverts commit 398cd4e5630a3e83d22d15286d7ac59b4c07c5d6.

refactor: use icon from resource manager

Also fixes incorrect path currently used in ts_qt.py.

nix(pyinstaller): replace use of sys.platform with platform.system

docs: add build section

Co-authored-by: Travis Abendshien <46939827+CyanVoxel@users.noreply.github.com>

nix/package/default.nix

@@ -0,0 +1,114 @@
+{
+  buildPythonApplication,
+  chardet,
+  ffmpeg-headless,
+  ffmpeg-python,
+  hatchling,
+  humanfriendly,
+  lib,
+  mutagen,
+  numpy,
+  opencv-python,
+  pillow,
+  pillow-heif,
+  pillow-jxl-plugin,
+  pipewire,
+  pydub,
+  pyside6,
+  pytest-qt,
+  pytest-xdist,
+  pytestCheckHook,
+  pythonRelaxDepsHook,
+  qt6,
+  rawpy,
+  send2trash,
+  sqlalchemy,
+  stdenv,
+  structlog,
+  syrupy,
+  ujson,
+  vtf2img,
+
+  withJXLSupport ? false,
+}:
+
+let
+  pyproject = (lib.importTOML ../../pyproject.toml).project;
+in
+buildPythonApplication {
+  pname = pyproject.name;
+  inherit (pyproject) version;
+  pyproject = true;
+
+  src = ../../.;
+
+  nativeBuildInputs = [
+    pythonRelaxDepsHook
+    qt6.wrapQtAppsHook
+  ];
+  buildInputs = [
+    qt6.qtbase
+    qt6.qtmultimedia
+  ];
+
+  nativeCheckInputs = [
+    pytest-qt
+    pytest-xdist
+    pytestCheckHook
+    syrupy
+  ];
+
+  makeWrapperArgs =
+    [ "--prefix PATH : ${lib.makeBinPath [ ffmpeg-headless ]}" ]
+    ++ lib.optional stdenv.hostPlatform.isLinux "--prefix LD_LIBRARY_PATH : ${
+      lib.makeLibraryPath [ pipewire ]
+    }";
+
+  pythonRemoveDeps = true;
+  pythonImportsCheck = [ "tagstudio" ];
+
+  build-system = [ hatchling ];
+  dependencies = [
+    chardet
+    ffmpeg-python
+    humanfriendly
+    mutagen
+    numpy
+    opencv-python
+    pillow
+    pillow-heif
+    pydub
+    pyside6
+    rawpy
+    send2trash
+    sqlalchemy
+    structlog
+    ujson
+    vtf2img
+  ] ++ lib.optional withJXLSupport pillow-jxl-plugin;
+
+  # INFO: These tests require modifications to a library, which does not work
+  # in a read-only environment.
+  disabledTests = [
+    "test_build_tag_panel_add_alias_callback"
+    "test_build_tag_panel_add_aliases"
+    "test_build_tag_panel_add_sub_tag_callback"
+    "test_build_tag_panel_build_tag"
+    "test_build_tag_panel_remove_alias_callback"
+    "test_build_tag_panel_remove_subtag_callback"
+    "test_build_tag_panel_set_aliases"
+    "test_build_tag_panel_set_parent_tags"
+    "test_build_tag_panel_set_tag"
+    "test_json_migration"
+    "test_library_migrations"
+  ];
+
+  meta = {
+    inherit (pyproject) description;
+    homepage = "https://docs.tagstud.io/";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ xarvex ];
+    mainProgram = "tagstudio";
+    platforms = lib.platforms.unix;
+  };
+}

nix/package/pillow-jxl-plugin.nix

@@ -0,0 +1,67 @@
+{
+  buildPythonPackage,
+  cmake,
+  fetchPypi,
+  lib,
+  numpy,
+  packaging,
+  pillow,
+  pyexiv2,
+  pytestCheckHook,
+  rustPlatform,
+}:
+
+buildPythonPackage rec {
+  pname = "pillow-jxl-plugin";
+  version = "1.3.2";
+  pyproject = true;
+
+  src = fetchPypi {
+    pname = builtins.replaceStrings [ "-" ] [ "_" ] pname;
+    inherit version;
+    hash = "sha256-efBoek8yUFR+ArhS55lm9F2XhkZ7/I3GsScQEe8U/2I=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit src;
+    hash = "sha256-vZHrwGfgo3fIIOY7p0vy4XIKiHoddPDdJggkBen+w/A=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    rustPlatform.cargoSetupHook
+    rustPlatform.maturinBuildHook
+  ];
+
+  nativeCheckInputs = [
+    numpy
+    pyexiv2
+    pytestCheckHook
+  ];
+
+  # INFO: Working directory takes precedence in the Python path. Remove
+  # `pillow_jxl` to prevent it from being loaded during pytest, rather than the
+  # built module, as it includes a `pillow_jxl.pillow_jxl` .so that is imported.
+  # See: https://github.com/NixOS/nixpkgs/issues/255262
+  # See: https://github.com/NixOS/nixpkgs/pull/255471
+  preCheck = ''
+    rm -r pillow_jxl
+  '';
+
+  dontUseCmakeConfigure = true;
+
+  pythonImportsCheck = [ "pillow_jxl" ];
+
+  dependencies = [
+    packaging
+    pillow
+  ];
+
+  meta = {
+    description = "Pillow plugin for JPEG-XL, using Rust for bindings.";
+    homepage = "https://github.com/Isotr0py/pillow-jpegxl-plugin";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ xarvex ];
+    platforms = lib.platforms.unix;
+  };
+}

nix/package/pyexiv2.nix

@@ -0,0 +1,32 @@
+{
+  autoPatchelfHook,
+  buildPythonPackage,
+  exiv2,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildPythonPackage rec {
+  pname = "pyexiv2";
+  version = "2.15.3";
+
+  src = fetchFromGitHub {
+    owner = "LeoHsiao1";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-83bFMaoXncvhRJNcCgkkC7B29wR5pjuLO/EdkQdqxxo=";
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook ];
+  buildInputs = [ exiv2.lib ];
+
+  pythonImportsCheck = [ "pyexiv2" ];
+
+  meta = {
+    description = "Read and write image metadata, including EXIF, IPTC, XMP, ICC Profile.";
+    homepage = "https://github.com/LeoHsiao1/pyexiv2";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ xarvex ];
+    platforms = with lib.platforms; darwin ++ linux ++ windows;
+  };
+}

nix/package/vtf2img.nix

@@ -0,0 +1,29 @@
+{
+  buildPythonPackage,
+  fetchPypi,
+  lib,
+  pillow,
+}:
+
+buildPythonPackage rec {
+  pname = "vtf2img";
+  version = "0.1.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-YmWs8673d72wH4nTOXP4AFGs2grIETln4s1MD5PfE0A=";
+  };
+
+  pythonImportsCheck = [ "vtf2img" ];
+
+  dependencies = [ pillow ];
+
+  meta = {
+    description = "A Python library to convert Valve Texture Format (VTF) files to images.";
+    homepage = "https://github.com/julienc91/vtf2img";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ xarvex ];
+    mainProgram = "vtf2img";
+    platforms = lib.platforms.unix;
+  };
+}

nix/shell.nix

@@ -0,0 +1,93 @@
+{
+  inputs,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  qt6Pkgs = import inputs.nixpkgs-qt6 { inherit (pkgs) system; };
+
+  pythonLibraryPath = lib.makeLibraryPath (
+    (with pkgs; [
+      fontconfig.lib
+      freetype
+      glib
+      stdenv.cc.cc.lib
+      zstd
+    ])
+    ++ (with qt6Pkgs.qt6; [ qtbase ])
+    ++ lib.optionals (!pkgs.stdenv.isDarwin) (
+      (with pkgs; [
+        dbus.lib
+        libGL
+        libdrm
+        libpulseaudio
+        libva
+        libxkbcommon
+        pipewire
+        xorg.libX11
+        xorg.libXrandr
+      ])
+      ++ (with qt6Pkgs.qt6; [ qtwayland ])
+    )
+  );
+  libraryPath = "${lib.optionalString pkgs.stdenv.isDarwin "DY"}LD_LIBRARY_PATH";
+
+  python = pkgs.python312;
+  pythonWrapped = pkgs.symlinkJoin {
+    inherit (python)
+      name
+      pname
+      version
+      meta
+      ;
+
+    paths = [ python ];
+
+    nativeBuildInputs = (with pkgs; [ makeWrapper ]) ++ (with qt6Pkgs.qt6; [ wrapQtAppsHook ]);
+    buildInputs = with qt6Pkgs.qt6; [ qtbase ];
+
+    postBuild = ''
+      wrapProgram $out/bin/python3.12 \
+        --prefix ${libraryPath} : ${pythonLibraryPath} \
+        "''${qtWrapperArgs[@]}"
+    '';
+  };
+in
+pkgs.mkShellNoCC {
+  nativeBuildInputs = with pkgs; [
+    coreutils
+
+    ruff
+  ];
+  buildInputs = [ pythonWrapped ] ++ (with pkgs; [ ffmpeg-headless ]);
+
+  env.QT_QPA_PLATFORM = "wayland;xcb";
+
+  shellHook =
+    let
+      python = lib.getExe pythonWrapped;
+    in
+    # bash
+    ''
+      if [ ! -f .venv/bin/activate ] || [ "$(readlink -f .venv/bin/python)" != "$(readlink -f ${python})" ]; then
+          printf '%s\n' 'Regenerating virtual environment, Python interpreter changed...' >&2
+          rm -rf .venv
+          ${python} -m venv .venv
+      fi
+
+      source .venv/bin/activate
+
+      if [ ! -f .venv/pyproject.toml ] || [ "$(cat .venv/pyproject.toml)" != "$(cat pyproject.toml)" ]; then
+          printf '%s\n' 'Installing dependencies, pyproject.toml changed...' >&2
+          pip install --quiet --editable '.[mkdocs,mypy,pytest]'
+          cp pyproject.toml .venv/pyproject.toml
+      fi
+    '';
+
+  meta = {
+    maintainers = with lib.maintainers; [ xarvex ];
+    platforms = lib.platforms.unix;
+  };
+}